source (j'suis pas sur que pastebin conserve vraiment les sources):
Code:
5 ' MIRE POUR THOMSON
10 CLEAR,,65
20 LOCATE 0,0,0:CONSOLE,,0
30 DEFINT A-Z
40 ' definition caracteres
50 FOR NIV=0 TO 64
60 LOCATE 0,0: PRINT USING "Definition niveau: ## ";NIV;
70 RESTORE 390
80 FOR I=0 TO 7
90 V(I) = 0: W=1
100 FOR J=0 TO 7
110 READ A
120 IF NIV>A THEN V(I)=V(I)+W
130 W = W*2
140 NEXT
150 NEXT
160 DEFGR$(NIV)=V(0),V(1),V(2),V(3),V(4),V(5),V(6),V(7)
170 PRINT GR$(NIV);" "
180 NEXT
190 NIV=64
200 PAL=15
210 BASE = 1+16+256
220 SCREEN 7,0,0:LOCATE 0,0:PRINT" "
230 PALETTE 1,PAL*BASE:BOXF(0,8)-(319,199),1
240 A=8:B=5
250 BOXF(A,B)-(39-A,25-B)GR$(NIV):PALETTE 1,PAL*273:CONSOLE,,1
260 DO
270 LOCATE 0,0: PRINT USING "pal==## niv==## (###%) pc==###";PAL;NIV;INT(NIV*100/64);INT(255*(NIV/64.0)^0.454545)
280 A$=INPUT$(1)
290 IF A$=CHR$(3) THEN EXIT
300 IF A$=CHR$(8) AND NIV>0 THEN NIV=NIV-1:BOXF(A,B)-(39-A,25-B)GR$(NIV)
310 IF A$=CHR$(9) AND NIV<64 THEN NIV=NIV+1:BOXF(A,B)-(39-A,25-B)GR$(NIV)
320 IF A$=CHR$(10) AND PAL>0 THEN PAL=PAL-1:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
330 IF A$=CHR$(11) AND PAL<15 THEN PAL=PAL+1:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
340 IF A$="0" THEN BASE=273:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
350 IF A$="1" THEN BASE=1:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
360 IF A$="2" THEN BASE=16:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
370 IF A$="3" THEN BASE=256:PALETTE 1,PAL*BASE:PALETTE 7,15*BASE
380 LOOP
390 DATA 0,48,12,60,3,51,15,63
400 DATA 32,16,44,28,35,19,47,31
410 DATA 8,56,4,52,11,59,7,55
420 DATA 40,24,36,20,43,27,39,23
430 DATA 2,50,14,62,1,49,13,61
440 DATA 34,18,46,30,33,17,45,29
450 DATA 10,58,6,54,9,57,5,53
460 DATA 42,26,38,22,41,25,37,21
Connexion
M’enregistrer
FAQ
Rechercher
)
