Logicielsmoto.com

Nous sommes le 29 Mar 2024, 00:00

Heures au format UTC + 1 heure




Poster un nouveau sujet Répondre au sujet  [ 11 messages ] 
Auteur Message
 Sujet du message: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 11:17 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
Hello,

c'est encore moi et mes "essais".
Cette fois-ci je m'attaque à la production de son sur le contrôleur "musique et jeu" au moyen du port B.

J'ai réussi à produire un belle onde sinusoïdale avec le code suivant :

Code:
(main)sound.asm   * Marquage du programme principal

CRB2   EQU $E7CF
DDRB2  EQU $E7CD
PORTB2 EQU $E7CD

    ORG $A000
DEBUT   
    PSHS U,Y,X,DP,D,CC
    JSR INIT
    JSR PLAY_START
FIN   
    PULS CC,D,DP,X,Y,U,PC ; PC == RTS

* -------------------
* SELECTION DU PORT B   
* -------------------
INIT               
    PSHS D
    CLRB
    STB  CRB2       ; CRB2 = 00
    LDD  #$3F04     ; D(A+B) = 0011 1111 0000 0100
    STA  DDRB2      ; DDRB2 = A = 3F = 0011 1111
    STB  CRB2       ; CRB2  = B = 04 = 0000 0100
    PULS D,PC       ; PC == RTS
   
* -------------------
* Routine sonore
* -------------------
PLAY_START
    PSHS Y,X,D,CC
    ORCC #$10       ; no interrupt

SIN_START   
    CLRB            ; B == increment de 0 -> 255
    LDX #SIN   

SEND_VALUE   
    LDA ,X+
    STA PORTB2      ; produire le son sur 6 bits ($00 to $3F)
    LDY #$0070      ; init valeur d'attente
    INCB           
    BEQ SIN_START   ; on recommence la SIN quand B == 0
    JMP SEND_VALUE  ; POUR L'INSTANT, BOUCLE INFINIE /!\

PLAY_END
    PULS CC,D,X,Y,PC ; PC == RTS
     
* ---------------------------------------------------------------------------------------     
* table de SINUS. l'amplitude est de 62 valeurs. (sur 64 possibles) de $01 (1) à $3E (62)     
* ---------------------------------------------------------------------------------------     
SIN
    FCB $20,$21,$22,$23,$23,$24,$25,$26,$26,$27,$28,$28,$29,$2A,$2B,$2B
    FCB $2C,$2D,$2D,$2E,$2F,$2F,$30,$31,$31,$32,$33,$33,$34,$34,$35,$35
    FCB $36,$36,$37,$37,$38,$38,$39,$39,$3A,$3A,$3A,$3B,$3B,$3C,$3C,$3C
    FCB $3C,$3D,$3D,$3D,$3D,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E
    FCB $3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3D,$3D,$3D,$3D,$3C,$3C
    FCB $3C,$3C,$3B,$3B,$3A,$3A,$3A,$39,$39,$38,$38,$37,$37,$36,$36,$35
    FCB $35,$34,$34,$33,$33,$32,$31,$31,$30,$2F,$2F,$2E,$2D,$2D,$2C,$2B
    FCB $2B,$2A,$29,$28,$28,$27,$26,$26,$25,$24,$23,$23,$22,$21,$20,$20
    FCB $1F,$1E,$1D,$1C,$1C,$1B,$1A,$19,$19,$18,$17,$17,$16,$15,$14,$14
    FCB $13,$12,$12,$11,$10,$10,$0F,$0E,$0E,$0D,$0C,$0C,$0B,$0B,$0A,$0A
    FCB $09,$09,$08,$08,$07,$07,$06,$06,$05,$05,$05,$04,$04,$03,$03,$03
    FCB $03,$02,$02,$02,$02,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01
    FCB $01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$02,$02,$02,$02,$03,$03
    FCB $03,$03,$04,$04,$05,$05,$05,$06,$06,$07,$07,$08,$08,$09,$09,$0A
    FCB $0A,$0B,$0B,$0C,$0C,$0D,$0E,$0E,$0F,$10,$10,$11,$12,$12,$13,$14
    FCB $14,$15,$16,$17,$17,$18,$19,$19,$1A,$1B,$1C,$1C,$1D,$1E,$1F,$20
    END DEBUT


Ca fonctionne bien, je suis content, ça donne ça :

phpBB [video]


J'ai voulu augmenter artificiellement la période de la sinusoïde, pour produire un son plus grave
J'ai donc rajouté une boucle de temporisation entre 2 changements de valeur :

Code:
* -------------------
* Routine sonore
* -------------------
PLAY_START
    PSHS Y,X,D,CC
    ORCC #$10       ; no interrupt

SIN_START   
    CLRB            ; B == increment de 0 -> 255
    LDX #SIN   

SEND_VALUE   
    LDA ,X+
    STA PORTB2      ; produire le son sur 6 bits ($00 to $3F)
    LDY #$0070      ; init valeur d'attente

* > Boucle de temporisation   
TEMPO                 
    LEAY -1,Y       ;                               
    BNE TEMPO       ; on boucle tant que Y != 0
* > Fin de boucle de temporisation   
    INCB           
    BEQ SIN_START   ; on recommence la SIN quand B == 0
    JMP SEND_VALUE  ; POUR L'INSTANT, BOUCLE INFINIE /!\

PLAY_END
    PULS CC,D,X,Y,PC ; PC == RTS


Mais je ne comprends pas le résultat obtenu.
J'aurais dû obtenir un son plus grave et à la place, il est plus aigu et, surtout, il ne semble pas correct.

phpBB [video]


Quand j'ouvre avec Audacity l'onde sonore :

Sans temporisation (son correct) :

Fichier(s) joint(s):
no-tempo.png
no-tempo.png [ 7.75 Kio | Vu 8318 fois ]


Avec temporisation (son incorrect) :

Fichier(s) joint(s):
tempo.png
tempo.png [ 7.51 Kio | Vu 8318 fois ]



Quelque chose m'échappe. Qu'est-ce que je ne fais (ou comprends) pas bien ?

PS : je pense que c'est Sam qui va me répondre :-)

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 13:24 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
J'ai refait quelques essais : c'est avec une temporisation de $9 que j'obtiens le son le plus grave, à partir de $10, le son produit n'est plus correct.

Code:
SEND_VALUE   
    LDY #$9     ; init valeur d'attente
    LDA ,X+       
* > Boucle de temporisation   
TEMPO   
    STA PORTB2      ; produire le son sur 6 bits ($00 to $3F)
    LEAY -1,Y       ;                               
    BNE TEMPO       ; on boucle tant que Y != 0


Quelqu'un pourrait m'éclairer ?

Au passage, quand je mets "STA PORTB2" dans la boucle de temporaisation, le son me semble + propre.

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 14:19 
Hors ligne

Inscription: 21 Avr 2019, 21:48
Messages: 433
Localisation: Var
Je n’ai pas l’ordi sous la main pour tester mais je pense que c’est un pb d’init.
je te copie un message de Daniel de 2005:
Citation:
La programmation du registre de direction du PIA est détaillé dans la datasheet du 6821 (à la page documentation de dcmoto). Il faut mettre à zero le bit 2 de E7CF pour accéder au registre de direction E7CD, envoyer &h3F dans ce registre, puis mettre à 1 le bit 2 de E7CF pour revenir en mode data sur E7CD.

C’est a faire après le orcc #$50 qui désactive les interruptions .

Et le code de prehisto pour l’init dac :
Code:
         ldd   #$fb3f
        anda  $e7cf
        sta   $e7cf
        stb   $e7cd
        ora   #$04
        sta   $e7cf


C’est ce que j’utilise et je n’ai pas de pb.


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 14:41 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
Peut-être que je suis sur des fréquences de SIN trop grandes pour le convertisseur aussi ... il doit y avoir une limite.

Avec le code modifié suite à ton message, j'ai le même comportement étrange quand je dépasse $9 pour le tempo.

Code:
(main)sound.asm   * Marquage du programme principal

CRB2   EQU $E7CF
DDRB2  EQU $E7CD
PORTB2 EQU $E7CD



    ORG $A000
DEBUT   
    PSHS U,Y,X,DP,D,CC
    ORCC #$50           ; no interrupt
    BSR INIT
    BSR PLAY_START
FIN   
    PULS CC,D,DP,X,Y,U,PC ; PC == RTS

* -------------------
* SELECTION DU PORT B   
* -------------------
INIT               
    PSHS D

    LDD   #$FB3F
    ANDA  CRB2
    STA   CRB2
    STB   DDRB2
    ORA   #$04
    STA   CRB2

    PULS D,PC       ; PC == RTS
   
* -------------------
* Routine sonore
* -------------------
PLAY_START
    PSHS Y,X,D
   

SIN_START   
    CLRB            ; B == increment de 0 -> 255
    LDX #SIN   

SEND_VALUE   
    LDY #$8     ; init valeur d'attente
    LDA ,X+       
* > Boucle de temporisation   
TEMPO   
    STA PORTB2      ; produire le son sur 6 bits ($00 to $3F)
    LEAY -1,Y       ;                               
    BNE TEMPO       ; on boucle tant que Y != 0
* > Fin de boucle de temporisation   
    INCB           
    BEQ SIN_START   ; on recommence la SIN quand B == 0
    JMP SEND_VALUE  ; POUR L'INSTANT, BOUCLE INFINIE /!\

PLAY_END
    PULS D,X,Y,PC ; PC == RTS
     
* ---------------------------------------------------------------------------------------     
* table de SINUS. l'amplitude est de 62 valeurs. (sur 64 possibles) de $01 (1) à $3E (62)     
* ---------------------------------------------------------------------------------------     
SIN
    FCB $20,$21,$22,$23,$23,$24,$25,$26,$26,$27,$28,$28,$29,$2A,$2B,$2B
    FCB $2C,$2D,$2D,$2E,$2F,$2F,$30,$31,$31,$32,$33,$33,$34,$34,$35,$35
    FCB $36,$36,$37,$37,$38,$38,$39,$39,$3A,$3A,$3A,$3B,$3B,$3C,$3C,$3C
    FCB $3C,$3D,$3D,$3D,$3D,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E
    FCB $3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3E,$3D,$3D,$3D,$3D,$3C,$3C
    FCB $3C,$3C,$3B,$3B,$3A,$3A,$3A,$39,$39,$38,$38,$37,$37,$36,$36,$35
    FCB $35,$34,$34,$33,$33,$32,$31,$31,$30,$2F,$2F,$2E,$2D,$2D,$2C,$2B
    FCB $2B,$2A,$29,$28,$28,$27,$26,$26,$25,$24,$23,$23,$22,$21,$20,$20
    FCB $1F,$1E,$1D,$1C,$1C,$1B,$1A,$19,$19,$18,$17,$17,$16,$15,$14,$14
    FCB $13,$12,$12,$11,$10,$10,$0F,$0E,$0E,$0D,$0C,$0C,$0B,$0B,$0A,$0A
    FCB $09,$09,$08,$08,$07,$07,$06,$06,$05,$05,$05,$04,$04,$03,$03,$03
    FCB $03,$02,$02,$02,$02,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$01
    FCB $01,$01,$01,$01,$01,$01,$01,$01,$01,$01,$02,$02,$02,$02,$03,$03
    FCB $03,$03,$04,$04,$05,$05,$05,$06,$06,$07,$07,$08,$08,$09,$09,$0A
    FCB $0A,$0B,$0B,$0C,$0C,$0D,$0E,$0E,$0F,$10,$10,$11,$12,$12,$13,$14
    FCB $14,$15,$16,$17,$17,$18,$19,$19,$1A,$1B,$1C,$1C,$1D,$1E,$1F,$20
    END DEBUT

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 15:34 
Hors ligne

Inscription: 21 Avr 2019, 21:48
Messages: 433
Localisation: Var
Pour l’instant je n’ai pas d’autres idées a part tester sur machine réelle ou avec dcmoto pour voir si le comportement est différent, mais je ne peux pas le faire en ce moment :-(


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 15:52 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
Bentoc a écrit:
Pour l’instant je n’ai pas d’autres idées a part tester sur machine réelle ou avec dcmoto pour voir si le comportement est différent, mais je ne peux pas le faire en ce moment :-(


C'est strictement pareil avec DCMOTO.


Je continue mes essais, mais cette fois-ci en générant un signal carré :

Code:
(main)sound.asm   * Marquage du programme principal

CRB2   EQU $E7CF
DDRB2  EQU $E7CD
PORTB2 EQU $E7CD

* -----------------------------------
* SUR le DAC, $1F = milieu de l'ondre sonore = 31 en decimal sur 64 valeurs (0..63)

LOW    EQU $0B    ; = $1F - $14
HIGH   EQU $33    ; = $1F + $14
WAIT   EQU $FF    ; temps d'attente sur la 1/2 periode

    ORG $A000
DEBUT   
    PSHS U,Y,X,DP,D,CC
    ORCC #$50           ; no interrupt
    BSR INIT
    BSR PLAY_START
FIN   
    PULS CC,D,DP,X,Y,U,PC ; PC == RTS

* -------------------
* SELECTION DU PORT B   
* -------------------
INIT               
    PSHS D

    LDD   #$FB3F
    ANDA  CRB2
    STA   CRB2
    STB   DDRB2
    ORA   #$04
    STA   CRB2

    PULS D,PC       ; PC == RTS
   
* -------------------
* Routine sonore
* -------------------
PLAY_START
    PSHS Y,D
 
PERIOD_START   

* > envoi de la valeur HIGH ---------------------------
    LDA #HIGH
    STA PORTB2   
   
* > Boucle de temporisation 1ere demi periode du signal
    LDY #WAIT     ; init valeur d'attente
TEMPO_1_PERIODE   
    LEAY -1,Y                                   
    BNE TEMPO_1_PERIODE
* > Fin de boucle de temporisation

* > envoi de la valeur LOW ----------------------------
    LDA #LOW 
    STA PORTB2    ; envoi de la valeur LOW
   
* > Boucle de temporisation 2nde demi-periode du signal 
    LDY #WAIT     ; init valeur d'attente
TEMPO_2_PERIODE   
    LEAY -1,Y                                     
    BNE TEMPO_2_PERIODE     
* > Fin de boucle de temporisation   

* > Relance une nouvelle periode
    JMP PERIOD_START  ; POUR L'INSTANT, BOUCLE INFINIE /!\

PLAY_END
    PULS D,Y,PC ; PC == RTS

    END DEBUT


Fichier(s) joint(s):
signal-carre.png
signal-carre.png [ 6.59 Kio | Vu 8302 fois ]


Ça marche parfaitement bien, le son est propre et le signal aussi. :D

Du coup, je me suis demandé, si émuler une puce YM-2149 (avec 3 channels distincts de signaux carrés) serait possible.
Vous voyez un obstacle ?
Samuel arrive bien à faire un modplayer, émuler le YM-2149 (Atari ST, C64, Amstrad, etc.) ce serait bien.

Pour info, mon article sur le YM-2149 pour Atari ST : https://www.fxjavadevblog.fr/m68k-atari-st-ym-player/


PS : je dois vous faire rire les pros du thomson avec mes essais de newbie / lamer ... :W

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 16:55 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
Avec l'exemple sur le signal carré avec boucle d'attente à $FF

Code:
     46                           * > envoi de la valeur HIGH ------------->>
     47  2     A021 86   33           LDA #HIGH
     48  5     A023 B7   E7CD         STA PORTB2
     49                           
     50                           * > Boucle de temporisation 1ere demi per>>
     51  4     A026 108E 00FF         LDY #WAIT     ; init valeur d'attente>>
     52        A02A               TEMPO_1_PERIODE
     53  4+1   A02A 31   3F           LEAY -1,Y
     54  3     A02C 26   FC           BNE TEMPO_1_PERIODE
     55                           * > Fin de boucle de temporisation
     56
     57                           * > envoi de la valeur LOW -------------->>
     58  2     A02E 86   0B           LDA #LOW
     59  5     A030 B7   E7CD         STA PORTB2    ; envoi de la valeur LO>>
     60                           
     61                           * > Boucle de temporisation 2nde demi-per>>
     62  4     A033 108E 00FF         LDY #WAIT     ; init valeur d'attente>>
     63        A037               TEMPO_2_PERIODE
     64  4+1   A037 31   3F           LEAY -1,Y
     65  3     A039 26   FC           BNE TEMPO_2_PERIODE
     66                           * > Fin de boucle de temporisation
     67
     68                           * > Relance une nouvelle periode
     69  4     A03B 7E   A021         JMP PERIOD_START  ; POUR L'INSTANT, B>>


> La boucle d'attente consomme 8 cycles pour 1 itération. (cf, lignes 53 et 54 : 4+1+3 = 8)

> Elle itère 256 fois, ce qui donne 2048 cycles

> Il y a 2 boucles d'attente, donc 4096 cycles consommés. (cf, lignes 63 et 64)

> l'affectation de valeur sur le port B consomme 2 fois 7 cycles, donc 14 cycles

> Comme 1 cycle = 0,000001 s sur notre processeur à 1 Mhz

> Ce qui donne 0,000001 x ((2048 x2) + 14 = 0,00411 s pour 1 période

> Ce qui donne la fréquence 1 / 0,00411 s = 243,30 Hz pour cette onde sonore.

Mes calculs sont corrects en vérifiant avec un générateur en ligne : https://onlinetonegenerator.com/?freq=2 ... orm=square

Et ce qui correspond avec le son émis par le TO8 :D

J'avance, j'avance :D

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 18:05 
Hors ligne

Inscription: 21 Aoû 2006, 09:06
Messages: 1802
Localisation: Brest
Oula il y a de l'activité par ici. Bon j'ai pas entendu ce qu'il se passe quand le son n'est pas bon, mais il n'y a pas de raisons que ca se passe plus mal que lorsqu'il est bon. A savoir aussi que comme le dit Bentoc il faut correctement initialiser le PIA (et couper le MUTE sur TO8/TO9 pour éviter que les déplacements de la souris perturbent le son.)

La première routine d'init ressemble à ce que je faisais sur TO7. As tu essayé de voir ce que donne DCMOTO en mode TO7/70 ?

Enfin pour l'init ou jouer des échantillons façon chiptune, il y a le logiciel Polyphonia et son player qui fait déjà cela. Sur le même site il y a aussi un article de Préhisto (notre maitre à tous) indiquant comment obtenir un son propre ce qui ferait un peu penser à ton soucis (mais tout se résume à la bonne initialisation du PIA).

_________________
Good morning, that's a nice Tnetennba


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 18:15 
Hors ligne

Inscription: 21 Aoû 2006, 09:06
Messages: 1802
Localisation: Brest
Autre chose
Code:
(6)    LDA ,X+
(5)    STA PORTB2      ; produire le son sur 6 bits ($00 to $3F)
(4)   LDY #$0070      ; init valeur d'attente

* > Boucle de temporisation   
TEMPO                 
(5)    LEAY -1,Y       ;                               
(3)    BNE TEMPO       ; on boucle tant que Y != 0
* > Fin de boucle de temporisation   
(2)    INCB           
(3)    BEQ SIN_START   ; on recommence la SIN quand B == 0
(4)    JMP SEND_VALUE  ; POUR L'INSTANT, BOUCLE INFINIE /!\

Si je compte "à la louche" les cycles il y a 6+5+4+8*$70+2+3+4 = 920 cycles par échantillons. Une période du sinus utilise j'imagine 256 échantillons, donc le sinus aura une période de 256*920 = 235 520µs, soit une fréquence de 4hz seulement !!!

Nous humains n'entendons plus rien à cette période et c'est pas mieux pour les dispositifs de capture: tu entends juste les irrégularités dans la sinusoïde (la valeur $20 est présent 4 fois dont au début et à la toute fin, on devrait en avoir 3, celle de fin arrive sur la période suivante et pas la fin de celle actuelle).

Bref l'attente avec $70 est bien trop lent et produit de l'infrason pour éléphants et baleines, mais pas pour les humains (20 à 20000 hz). Avec la valeur 9, tu tombes à 96 cycles par échantillon, 25ms par période de sinusoide --> soit 40hz ce qui me semble plus audible. A noter que la boucle de base fournit déjà un son plutôt grave (162hz si je compte bien). Tu devrais essayer de démarrer à une fréquence plus haute (caser plusieurs période de sinus dans les 256 valeurs du tableau).

Autre truc pour la vitesse: n'utilise pas ",x+" mais le mode indexe c'est plus rapide: B peut servir à la fins d'indexe dans le tableau et de compteur à 256. Tu peux même te permettre d'avoir un compteur sur 16 bits dont les 8 bits de poids fort te donnent l'index entier et ceux de poids faible l'indexe fractionnaire ce qui permet un contrôle plus fin de la fréquence.

Regarde par exemple ce que donnerait ce code avec ta table de sinus sur 256 valeurs:
Code:
NOTE equ 256
    LDX #SIN+128   
    LDD #0  ; en fait peu importe
LOOP
(4)    ADDD #NOTE
(6)    PSHS B  ; optimisable, mais c'est laissé en l'exercice
(5)    LDB  A,X
(6)    STB PORTB2      ; produire le son sur 6 bits ($00 to $3F)
(6)    PULS B
(3)    BRA LOOP
avec NOTE=256 on avance d'exactement 1 échantillon par tour (30 cycles si je ne me trompe pas) soit une période de 7ms680 avec la table de sinus.

Ca jouera donc un truc à 136hz... mais si tu fais NOTE=512, et bien ca jouera à l'octave au dessus (plus aigu), ou avec NOTE=128 l'octave en dessous (plus grave). Une règle de 3 nous indique que NOTE=825 devrait nous jouer un LA440. Bref en modifiant la valeur de NOTE régulièrement (dans une routine d'interruption par exemple), tu modifiera la note jouée et ca commencera par ressembler à de la musique :)

PS: sous réserve d'erreurs de calcul.. je fais ca rapidement et de mémoire, sans documentation.

_________________
Good morning, that's a nice Tnetennba


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 28 Juil 2021, 20:17 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
Samuel Devulder a écrit:
Autre chose [code]
Bref l'attente avec $70 est bien trop lent et produit de l'infrason pour éléphants et baleines


:W C'est pour cela les baleines et les éléphants sous ma fenêtre pendant mes essais :-)

Merci pour toute cette analyse que j'aurais dû faire ... :bah:

Oui pour l'accès indexé, d'ailleurs j'avais fait comme ça au début, puis face à mes "problèmes" j'ai remis ",X+"

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
 Sujet du message: Re: [TO8] Production Sonore
MessagePosté: 29 Juil 2021, 10:55 
Hors ligne

Inscription: 12 Fév 2021, 15:54
Messages: 78
Localisation: Rennes
Et merci pour les liens vers les articles de Prehisto, c'est une mine d'informations exceptionnelles ! :good:

_________________
Fan de Atari 2600, Thomson MO5, Thomson TO8, Atari STE.
Retro-Codeur à mes heures perdues. https://www.fxjavadevblog.fr


Haut
 Profil  
Répondre en citant le message  
Afficher les messages postés depuis:  Trier par  
Poster un nouveau sujet Répondre au sujet  [ 11 messages ] 

Heures au format UTC + 1 heure


Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 38 invités


Vous ne pouvez pas poster de nouveaux sujets
Vous ne pouvez pas répondre aux sujets
Vous ne pouvez pas éditer vos messages
Vous ne pouvez pas supprimer vos messages
Vous ne pouvez pas joindre des fichiers

Rechercher:
Aller à:  
cron
Développé par phpBB® Forum Software © phpBB Group
Traduction par phpBB-fr.com